Amiga Tools 5/Amiga Tools 5.iso/tools/system-tools/tinymeter/install

Text File | 1996-03-22 | 10.6 KB | 352 lines

; Installer Script for TinyMeter V4.22+

;*******************************************************************************************
; ENGLISH
;
(set @def_lang          0)
(set @def_help          "Where's the problem?")
(set @where_main        "Where should I copy the TinyMeter main program ?")
(set @where_main_help   "SYS:WBStartup is the best place. Simply click proceed.")
(set @where_prefs       "Where should I copy the TinyMeter preferences program?")
(set @where_prefs_help  "SYS:Prefs is the best place, since TinyMeter can only call it, when its there.")
(set @which_lang        "Which languages should be installed?")
(set @which_icons       "Which icons do you use")
(set @which_install     "What should be installed?")
(set @choic_1           "Example settings")
(set @choic_2           "Fonts for Clocks")
(set @choic_3           "Background patterns")
(set @choic_4           "Pictograms for launchermenus")
(set @choic_5           "Documentation")
(set @where_picto       "Where should the pictograms be installed?")
(set @where_picto_help  "Prefs:Pictograms is the best place. Simply click proceed.")
(set @where_docs        "Where should the documentation be installed?")
(set @where_docs_help   "HELP: is the best place. The HELP key is only available within the preferences program when you put it here. Simply click proceed.")
(set @where_fonts       "Where should the fonts be installed?")
(set @where_fonts_help  "FONTS: is the best place. The AmigaOS normally can only use fonts which are installed here. Simply click proceed.")
(set @where_back        "Where should the background patterns be installed?\n (example settings-file uses SYS:Prefs/Patterns!)")
(set @insta_files       "Installing the files...")
(set @insta_main        "Installing TinyMeter...")
(set @insta_catalog     "Installing catalog...")
(set @insta_newicons    "Installing NewIcons®...")
(set @insta_examples    "Installing example settings...")
(set @insta_fonts       "Installing fonts...")
(set @insta_backs       "Installing patterns...")
(set @insta_pictos      "Installing pictograms...")
(set @insta_docs        "Installing documentation...")
(set @insta_def         "Installing...")
(set @messa_exit        "Have phun with this nice piece of soft!!!\n\nNow you should start TinyMeter, setup the position and size and press S to save these settings.\n\nAfter that, start the TinyMeter preferences to setup TinyMeter to your personal taste.\n\nIf there are any problems, don't hesitate to contact the author!")

;*******************************************************************************************
; DEUTSCH
;
(if (= @language "deutsch")
    (
    (set @def_lang          1)
    (set @def_help          "Wo ist das Problem?")
    (set @where_main        "Wohin soll das Hauptprogramm kopiert werden?")
    (set @where_main_help   "SYS:WBStartup ist der Beste Platz.")
    (set @where_prefs       "Wohin soll das Einstellungsprogramm kopiert werden?")
    (set @where_prefs_help  "SYS:Prefs ist der Beste Platz.")
    (set @which_lang        "Welche Sprachen sollen installiert werden?")
    (set @which_icons       "Welche Icons sollen benutzt werden?")
    (set @which_install     "Was soll installiert werden?")
    (set @choic_1           "Beispieleinstellungen")
    (set @choic_2           "Zeichensätze für die Uhr")
    (set @choic_3           "Hintergrundbilder")
    (set @choic_4           "Piktogramme für die Schnellstarter")
    (set @choic_5           "Dokumentation")
    (set @where_picto       "Wohin sollen die Piktogramme opiert werden?")
    (set @where_picto_help  "Prefs:Pictograms ist der Beste Platz.")
    (set @where_docs        "Wohin soll die Doumentation kopiert werden?")
    (set @where_docs_help   "HELP: ist der Beste Platz.")
    (set @where_fonts       "Wohin sollen die Zeichensätze opiert werden?")
    (set @where_fonts_help  "FONTS: ist der Beste Platz..")
    (set @where_back        "Wohin sollen die Hintergrundbilder opiert werden?\n (Die Beispiel einstellungen benötigen diese Bilder!)")
    (set @insta_files       "Installiere Dateien...")
    (set @insta_main        "Installiere TinyMeter...")
    (set @insta_catalog     "Installiere Sprachenkataloge...")
    (set @insta_newicons    "Installiere NewIcons®...")
    (set @insta_examples    "Installiere Beispieleinstellungen...")
    (set @insta_fonts       "Installiere Zeichensätze...")
    (set @insta_backs       "Installiere Hintergrundbilder...")
    (set @insta_pictos      "Installiere Piktogramme...")
    (set @insta_docs        "Installiere Doumentation...")
    (set @insta_def         "Installiere...")
    (set @messa_exit        "Nun viel Spaß mit diesem Programm!!!\n\nNun sollte man TinyMeter starten, die Position und Größe einstellen, S druecken und mit dem Einstellungsprogramm weitere Einstellungen vornehmen.\nBei Problemen ist der Author immer über EMail oder auf IRC erreichbar.")
    )
)

;*******************************************************************************************
; FRANÇAIS
;
(if (= @language "français")
    (
    (set @def_lang          2)
    (set @def_help          "Où est le problème?")
    (set @where_main        "Où voulez vous installer TinyMeter?")
    (set @where_main_help   "SYS:WBStartup est la meilleur destination.")
    (set @where_prefs       "Où voulez vous installer le programme de réglage?")
    (set @where_prefs_help  "SYS:Prefs es la meilleur destination.")
    (set @which_lang        "Quelle langues voulez vous installer?")
    (set @which_icons       "Quelle type d´icônes vous utiliséz?")
    (set @which_install     "Qu´est-ce qu´il faut installer?")
    (set @choic_1           "Examples")
    (set @choic_2           "Polices pour l´horloge")
    (set @choic_3           "Images de fond")
    (set @choic_4           "Pictogrammes pour les lanceurs")
    (set @choic_5           "Documentation")
    (set @where_picto       "Où voulez vous installer les pictogrammes?")
    (set @where_picto_help  "Prefs:Pictograms est la meilleur destination.")
    (set @where_docs        "Où voulez vous installer la documentation?")
    (set @where_docs_help   "HELP: est la meilleur destination.")
    (set @where_fonts       "Où voulez vous installer les polices?")
    (set @where_fonts_help  "FONTS: est la meilleur destination.")
    (set @where_back        "Où voulez vous installer les images de fond?")
    (set @insta_files       "Installation en cours...")
    (set @insta_main        "Installation en cours...")
    (set @insta_catalog     "Installation en cours...")
    (set @insta_newicons    "Installation en cours...")
    (set @insta_examples    "Installation en cours...")
    (set @insta_fonts       "Installation en cours...")
    (set @insta_backs       "Installation en cours...")
    (set @insta_pictos      "Installation en cours...")
    (set @insta_docs        "Installation en cours...")
    (set @insta_def         "Installation en cours...")
    (set @messa_exit        "S´il y a des problèmes, n´hésitez pas de contacter l´auteur!")
    )
)

(set @default-dest (""))

(set @source-file "TinyMeter")

(set @destdir
    (askdir
        (prompt @where_main)
        (help @where_main_help)
        (default "SYS:WBStartup/")
    )
)
(set @prefsdir
    (askdir
        (prompt @where_prefs)
        (help @where_prefs_help)
        (default "SYS:Prefs/")
    )
)
(set langchoice
    (askoptions
        (prompt @which_lang)
        (help @def_help)
        (choices "Deutsch" "Français" "Italiano" "Polski")
        (default @def_lang)
    )
)

(set iconchoice
    (askchoice
        (prompt @which_icons)
        (help @def_help)
        (choices "MagicWB®" "NewIcons®")
        (default 0)
    )
)

(set instchoice
    (askoptions
        (prompt @which_install)
        (help @def_help)
        (choices @choic_1 @choic_2 @choic_3 @choic_4 @choic_5)
        (default 8)
    )
)

(if (<> 0 (BITAND instchoice 8))
    (set @picdir
    (askfile
        (prompt @where_picto)
        (help @where_picto_help)
        (default "SYS:Prefs/Pictograms")
    )
    )
)

(if (<> 0 (BITAND instchoice 16))
    (set @helpdir
        (askdir
            (prompt @where_docs)
            (help @where_docs_help)
            (default "HELP:")
        )
    )
)

(if (<> 0 (BITAND instchoice 2))
    (set @fontdir
        (askdir
            (prompt @where_fonts)
            (help @where_fonts_help)
            (default "FONTS:")
        )
    )
)

(if (<> 0 (BITAND instchoice 4))
    (set @pattdir
        (askdir
            (prompt @where_back)
            (help @def_help)
            (default "SYS:Prefs/")
        )
    )
)

(copyfiles
    (prompt @insta_files)
    (help @def_help)
    (source @source-file)
    (infos)
    (newname "TinyMeter")
    (dest @destdir)
)

(copyfiles
    (prompt @insta_main)
    (help @def_help)
    (source "Prefs/TinyMeter")
    (infos)
    (newname "TinyMeter")
    (dest @prefsdir)
)

(if (<> 0 (BITAND langchoice 1))
    (copyfiles
        (prompt @insta_catalog)
        (help @def_help)
        (source "Catalogs/deutsch/TinyMeterPrefs.catalog")
        (dest "LOCALE:Catalogs/deutsch/")
    )
)
(if (<> 0 (BITAND langchoice 2))
    (copyfiles
        (prompt @insta_catalog)
        (help @def_help)
        (source "Catalogs/français/TinyMeterPrefs.catalog")
        (dest "LOCALE:Catalogs/français/")
    )
)
(if (<> 0 (BITAND langchoice 4))
    (copyfiles
        (prompt @insta_catalog)
        (help @def_help)
        (source "Catalogs/italiano/TinyMeterPrefs.catalog")
        (dest "LOCALE:Catalogs/italiano/")
    )
)
(if (<> 0 (BITAND langchoice 8))
    (copyfiles
        (prompt @insta_catalog)
        (help @def_help)
        (source "Catalogs/polski/TinyMeterPrefs.catalog")
        (dest "LOCALE:Catalogs/polski/")
    )
)
(if (<> 0 (BITAND iconchoice 1))
    (copyfiles
        (prompt @insta_newicons)
        (help @def_help)
        (source "ArtWork/newicons/TinyMeter.info")
        (dest @destdir)
    )
)
(if (<> 0 (BITAND iconchoice 1))
    (copyfiles
        (prompt @insta_newicons)
        (help @def_help)
        (source "ArtWork/newicons/TinyMeterPrefs.info")
        (newname "TinyMeter.info")
        (dest @prefsdir)
    )
)

(if (<> 0 (BITAND instchoice 1))
    (copyfiles
        (prompt @insta_examples)
        (help @def_help)
        (source "Examples/MagicWB.tm")
        (newname "TinyMeter")
        (dest "ENV:")
    )
)

(if (<> 0 (BITAND instchoice 1))
    (copyfiles
        (prompt @insta_examples)
        (help @def_help)
        (source "Examples/MagicWB.tm")
        (newname "TinyMeter")
        (dest "ENVARC:")
    )
)

(if (<> 0 (BITAND instchoice 2))
    (copyfiles
        (prompt @insta_fonts)
        (help @def_help)
        (source "ArtWork/Fonts/")
        (all)
        (dest @fontdir)
    )
)

(if (<> 0 (BITAND instchoice 4))
    (copyfiles
        (prompt @insta_backs)
        (help @def_help)
        (source "ArtWork/Patterns/")
        (all)
        (dest @pattdir)
    )
)

(if (<> 0 (BITAND instchoice 16))
    (copyfiles
        (prompt @insta_docs)
        (help @def_help)
        (source "TinyMeter.guide")
        (infos)
        (dest @helpdir)
    )
)

(if (<> 0 (BITAND instchoice 8))
    (copyfiles
        (prompt @insta_pictos)
        (help @def_help)
        (source "ArtWork/Pictogram/")
        (all)
        (dest @picdir)
    )
)

(copylib
    (prompt @insta_def)
    (help @def_help)
    (source "Libs/screennotify.library")
    (dest "LIBS:")
    (confirm)
)

(copylib
    (prompt @insta_def)
    (help @def_help)
    (source "Libs/wbstart.library")
    (dest "LIBS:")
    (confirm)
)


(exit
    @messa_exit
)